plugins {
	id("java")
	id("maven-publish")
	id("com.github.johnrengelman.shadow") version "8.1.1"
	id("io.papermc.paperweight.userdev") version "1.7.1"
	kotlin("jvm") version libs.versions.kotlin
	kotlin("kapt") version libs.versions.kotlin
}

group = "club.mcscrims"
version = "1.0.0"

repositories {
	mavenCentral()
	maven("https://repo.papermc.io/repository/maven-public/")
	maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
	maven("https://oss.sonatype.org/content/repositories/snapshots/")
	maven("https://libraries.minecraft.net/")
	maven("https://repo.codemc.io/repository/maven-public/")

	maven {
		url = uri("https://maven.pkg.github.com/McScrims-Network/Main-CoreSystem")
		credentials {
			username = System.getenv("GITHUB_ACTOR")
			password = System.getenv("GITHUB_TOKEN")
		}
	}
}

dependencies {
	implementation("org.mongodb:mongodb-driver-kotlin-coroutine:4.11.1")
	implementation("org.mongodb:bson-kotlinx:4.11.1")

	implementation("net.kyori:adventure-api:4.14.0")
	implementation("net.kyori:adventure-text-minimessage:4.14.0")
	implementation("net.kyori:adventure-platform-bukkit:4.3.2")

	compileOnly("net.luckperms:api:5.4")

	implementation("club.mcscrims:core:1.4.2")
	implementation("club.mcscrims:spigot:1.4.2")

	compileOnly("io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT")
	paperweight.paperDevBundle("1.21.1-R0.1-SNAPSHOT")
}

tasks {
	compileKotlin {
		compilerOptions.freeCompilerArgs.set(listOf( "-Xjsr305=strict" ))
	}

	compileJava {
		options.encoding = "UTF-8"
	}

	shadowJar {
		archiveBaseName.set("GameModes-SpeedHG")
		archiveClassifier.set("")
		archiveVersion.set(project.version.toString())
	}

	assemble {
		dependsOn( reobfJar )
	}

	build {
		dependsOn( shadowJar )
	}
}

java {
	toolchain.languageVersion.set(JavaLanguageVersion.of( 21 ))
}